#include <M5Atom.h>
#include <WiFi.h>
#include <Ambient.h>

//define
//スリープ時間計算マクロ関数
#define SLEEP_MIN(min) min*60000000ULL
//色定義　GRBの順番に注意
#define LED_PINK 0x55FFAA
#define LED_GREEN 0xFF0022
#define LED_BLUE 0x0022FF
#define LED_OFF 0x000000
//pin定義
const uint8_t kEarthPin = 32;
//スリープ時間
const uint sleepMin = 30; //30分
//wifi情報
const char wifi_ssid[32]="SSID";
const char wifi_key[64]="アクセスポイントのキー";
//ambient情報
const unsigned int channelId = 0; // AmbientのチャネルID
const char* writeKey = "ライトキー";
//static変数
WiFiClient client;
Ambient ambient;

//functions
//測定
void measureEarth(){

  //5回計測した平均を送る
  uint16_t earthVal = 0;
  int measureNum = 5;
  for(int i=0; i<measureNum; i++)
  {
    M5.dis.fillpix(LED_GREEN);    //LED点灯
    delay(200);
    //水分センサは濡れているほうが値が低くなるので反転させる
    earthVal += 1024 - analogRead(kEarthPin);
    M5.dis.fillpix(LED_OFF);    //LEDオフ
    delay(300);
  }
  earthVal/= measureNum;
  ambient.set(1,earthVal);

  //Ambient送信
  ambient.send();
  
}

//カウントダウン
void countDown(const char *dispTxt,const int sec)
{
  int count = sec;
  while (count >= 0)
  {
    count--;
    M5.dis.fillpix(LED_PINK);    //LEDオン
    //1秒待つ
    delay(500);
    M5.dis.fillpix(LED_OFF);    //LEDオフ
    delay(500);
  }
}

//setup関数　ディープスリープ復帰時もここから再開する
void setup() {
  //M5スタート
  M5.begin();

  //水分センサのピンをセットアップ
  pinMode(kEarthPin,ANALOG);

  //アナログ値の解像度を1024段階に設定
  analogSetWidth(10); //10bit(1024)

  // WiFi接続
  Serial.printf("Connecting to %s ", wifi_ssid);
  WiFi.begin(wifi_ssid, wifi_key);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("CONNECTED");

  //Ambient setup
  ambient.begin(channelId, writeKey, &client); // チャネルIDとライトキーを指定してAmbientの初期化
}

void loop() {
  //計測カウントダウン
  countDown("measure",5);

  //計測
  measureEarth();
  
  //wait
  delay(5000);

  //スリープカウントダウン
  countDown("sleep",5);

  //スリープ
  Serial.println("Enter sleep");
  esp_sleep_enable_timer_wakeup(SLEEP_MIN(sleepMin));
  esp_deep_sleep_start();
}